Cómo llamar a agentes de Vertex AI desde el entorno de ABAP

En esta guía de inicio rápido, se muestra cómo llamar a los agentes de Vertex AI, compilados con el kit de desarrollo de agentes (ADK), desde tu entorno de ABAP.

En esta guía, se explica el proceso de llamar a un agente de IA con la edición local o en la nube del SDK de ABAP para Google Cloud, y no se abordan los procedimientos de creación o implementación. Puedes crear un agente de IA con el kit de desarrollo de agentes (ADK), que es un framework de código abierto para diseñar agentes, creado en el mismo framework que potencia Google Agentspace y el Customer Engagement Suite con Google AI. Luego, implementas tu agente en Vertex AI Agent Engine, que es un entorno de ejecución completamente administrado en Vertex AI que te ayuda a implementar tus agentes personalizados en producción con pruebas, lanzamientos y confiabilidad integrados a una escala global y segura.

Antes de comenzar

Antes de ejecutar esta guía de inicio rápido, asegúrate de que tú o tus administradores hayan completado los siguientes requisitos previos:

Implementa el agente en Vertex AI Agent Engine

Crea, prueba y, luego, implementa tu agente en Vertex AI Agent Engine. En esta guía de inicio rápido, puedes crear un agente de clima y hora y, luego, implementarlo en Vertex AI Agent Engine.

Para obtener información sobre cómo crear, probar e implementar tu agente, consulta lo siguiente:

Asegúrate de haber otorgado los permisos necesarios para que el agente use sesiones administradas.

Después de la implementación, obtienes un identificador de recursos similar al siguiente ejemplo, que habilita la invocación de agentes dentro de tu programa ABAP:

AgentEngine created. Resource name: projects/project_id/locations/us-central1/reasoningEngines/REASONING_ENGINE_ID

En el identificador de recursos, toma nota del REASONING_ENGINE_ID, por ejemplo, 6384464913570601984. La necesitarás en un paso posterior.

Crea un programa para llamar a Vertex AI Agents desde el entorno de ABAP

  1. En el sistema SAP, crea un programa ejecutable en tu espacio de nombres personalizado (por ejemplo, Z o Y) mediante la transacción SE38.

    1. En la GUI de SAP, ingresa el código de transacción SE38.

    2. En el campo Programa, ingresa un nombre para tu programa, por ejemplo, ZDEMO_CALL_AGENT.

    3. Haz clic en Crear.

    4. Especifica los atributos del programa:

      1. En el campo Título, ingresa un título para el programa, por ejemplo, Call Vertex AI Agent.

      2. En el campo Tipo, selecciona Executable Program.

      3. Haz clic en Guardar.

    5. Guarda el programa como un objeto local.

    6. En el Editor de ABAP, agrega el siguiente código:

        REPORT zdemo_call_agent.

  DATA lv_p_projects_id          TYPE string.
  DATA lv_p_locations_id         TYPE string.
  DATA lv_p_reasoning_engines_id TYPE string.
  DATA ls_input                  TYPE /goog/cl_aiplatform_v1=>ty_1072.

  TYPES: BEGIN OF ty_agent_input,
          message    TYPE string,
          session_id TYPE string,
          user_id    TYPE string,
        END OF ty_agent_input.

  DATA ls_agent_input TYPE ty_agent_input.

  TYPES: BEGIN OF ty_response,
          content TYPE /goog/cl_aiplatform_v1=>ty_695,
        END OF ty_response.
  DATA ls_agent_response TYPE ty_response.

  TRY.

      " Open HTTP Connection
      DATA(lo_client) = NEW /goog/cl_aiplatform_v1( iv_key_name = 'DEMO_AIPLATFORM' ).
      DATA lv_agent_response_txt TYPE string.

      " Populate relevant parameters
      lv_p_projects_id = lo_client->gv_project_id.
      lv_p_locations_id = 'LOCATION_ID'.
      lv_p_reasoning_engines_id = 'REASONING_ENGINE_ID'.

      ls_agent_input-message = 'What is the weather in New York'. "Prompt
      ls_agent_input-user_id = 'use-101'.
      ls_input-class_method = 'stream_query'.
      GET REFERENCE OF ls_agent_input INTO ls_input-input.

      lo_client->add_json_name_mapping( iv_abap = 'CLASS_METHOD' iv_json = 'class_method' ).
      lo_client->add_json_name_mapping( iv_abap = 'SESSION_ID'  iv_json = 'session_id' ).
      lo_client->add_json_name_mapping( iv_abap = 'USER_ID' iv_json = 'user_id' ).

      " Call API method: aiplatform.projects.locations.reasoningEngines.streamQuery
      lo_client->stream_query_reasoning_engi( EXPORTING iv_p_projects_id          = lv_p_projects_id
                                                        iv_p_locations_id         = lv_p_locations_id
                                                        iv_p_reasoning_engines_id = lv_p_reasoning_engines_id
                                                        is_input                  = ls_input
                                              IMPORTING es_raw                    = lv_agent_response_txt
                                                        ev_ret_code               = DATA(lv_ret_code)
                                                        ev_err_text               = DATA(lv_err_text)
                                                        es_err_resp               = DATA(ls_err_resp) ).

      " Handle the output
      IF lo_client->is_success( lv_ret_code ).
        SPLIT lv_agent_response_txt AT cl_abap_char_utilities=>newline INTO TABLE DATA(lt_result_event_tab).

        " Deserialize to read the final response event from agent
        /goog/cl_json_util=>deserialize_json( EXPORTING iv_json        = lt_result_event_tab[ 3 ]
                                                        iv_pretty_name = /ui2/cl_json=>pretty_mode-extended
                                              IMPORTING es_data        = ls_agent_response ).

        cl_demo_output=>display( ls_agent_response-content-parts[ 1 ]-text ).

      ELSE.
        MESSAGE lv_err_text TYPE 'E'.
      ENDIF.

      " Close HTTP Connection
      lo_client->close( ).

    CATCH /goog/cx_sdk INTO DATA(lo_exception).
      MESSAGE lo_exception->get_text( ) TYPE 'E'.
  ENDTRY.

      Reemplaza lo siguiente:

      • DEMO_AIPLATFORM: Es la clave del cliente para la autenticación en Google Cloud.
      • LOCATION_ID: Es la ubicación en la que se implementa el agente. Especificas la ubicación cuando inicializas el agente. Para obtener más información, consulta Inicializa el agente.
      • REASONING_ENGINE_ID: Es el identificador de recursos del agente que anotaste en la sección Implementa el agente en el motor de agentes de Vertex AI.

  2. Ejecuta tu aplicación en SE38.

  3. Valida que los resultados sean coherentes con los que se observaron cuando se ejecutó el agente de forma local.

    Example response: OK. The weather in New York is sunny with a temperature of 25 degrees Celsius (41 degrees Fahrenheit).

¿Qué sigue?