此代码示例可用于翻译 Cloud Storage 存储桶中一个或多个受支持类型的文件，并将翻译后的文件存储到目标 Cloud Storage 存储桶。对于批量翻译，该服务账号必须具有访问 Cloud Storage 存储桶的额外权限以及执行翻译操作的权限。如需了解详情，请参阅翻译文档。
如需查看 SAP BTP 版本的 ABAP SDK for Google Cloud 代码示例的全面集合，请参阅 GitHub 上的代码示例代码库。
如需查看本地或任何云版本的 ABAP SDK for Google Cloud 代码示例的全面集合，请参阅 GitHub 上的代码示例代码库。
代码示例
SAP BTP 版本
" --------------------------------------------------------------------
" Copyright 2024 Google LLC -
" -
" Licensed under the Apache License, Version 2.0 (the "License"); -
" you may not use this file except in compliance with the License. -
" You may obtain a copy of the License at -
" https://www.apache.org/licenses/LICENSE-2.0 -
" Unless required by applicable law or agreed to in writing, -
" software distributed under the License is distributed on an -
" "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, -
" either express or implied. -
" See the License for the specific language governing permissions -
" and limitations under the License. -
" --------------------------------------------------------------------
CLASS zcl_cs_translate_doc_in_batch DEFINITION
PUBLIC FINAL
CREATE PUBLIC.
PUBLIC SECTION.
INTERFACES if_oo_adt_classrun.
ENDCLASS.
CLASS ZCL_CS_TRANSLATE_DOC_IN_BATCH IMPLEMENTATION.
METHOD if_oo_adt_classrun~main.
" Data Declarations
DATA lv_p_projects_id TYPE string.
DATA lv_p_locations_id TYPE string.
DATA lv_input_uri TYPE string.
DATA lv_output_uri TYPE string.
DATA ls_input TYPE /goog/cl_translation_v3=>ty_003.
TRY.
" Open HTTP Connection
" Pass the configured client key, TRANSLATE_DEMO is used as example, replace it with actual value
DATA(lo_translate) = NEW /goog/cl_translation_v3( iv_key_name = 'TRANSLATE_DEMO' ).
" Populate the data that needs to be passed to the API
" Derive project id
lv_p_projects_id = lo_translate->gv_project_id.
" Pass location id, us-central1 is used as an example, replace it with actual value.
lv_p_locations_id = 'us-central1'.
" TODO: Provide values for source and target cloud storage buckets
"lv_input_uri =
"lv_output_uri =
"Values passed for source language code and target language codes are examples.
"Replace them with actual values.
ls_input = VALUE #(
source_language_code = 'en-US'
target_language_codes = VALUE #( ( `es-ES` )
( `fr-FR` ) )
input_configs = VALUE #( ( gcs_source = VALUE #( input_uri = lv_input_uri ) ) )
output_config = VALUE #(
gcs_destination = VALUE #( output_uri_prefix = lv_output_uri ) ) ).
" Call the API
lo_translate->batch_translate_document_lo( EXPORTING iv_p_projects_id = lv_p_projects_id
iv_p_locations_id = lv_p_locations_id
is_input = ls_input
IMPORTING es_output = DATA(ls_output)
ev_ret_code = DATA(lv_ret_code)
ev_err_text = DATA(lv_err_text)
es_err_resp = DATA(ls_err_resp) ).
IF /goog/cl_http_client=>is_success( lv_ret_code ).
" This returns a long running operation id as glossary creation is adhoc
" You can use the LRO ID to poll and check the status of the operation
out->write( |LRO ID: { ls_output-name }| ).
ELSE.
out->write( | Error occurred: { lv_err_text }| ).
ENDIF.
" Close HTTP Connection
lo_translate->close( ).
CATCH /goog/cx_sdk INTO DATA(lo_sdk_excp).
lv_err_text = lo_sdk_excp->get_text( ).
out->write( |Exception occurred: { lv_err_text } | ).
ENDTRY.
ENDMETHOD.
ENDCLASS.
本地或任何云版本
**********************************************************************
* Copyright 2023 Google LLC *
* *
* Licensed under the Apache License, Version 2.0 (the "License"); *
* you may not use this file except in compliance with the License. *
* You may obtain a copy of the License at *
* https://www.apache.org/licenses/LICENSE-2.0 *
* Unless required by applicable law or agreed to in writing, *
* software distributed under the License is distributed on an *
* "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, *
* either express or implied. *
* See the License for the specific language governing permissions *
* and limitations under the License. *
**********************************************************************
REPORT zr_batch_translate_document_lo.
"Data Declarations
DATA:
lv_p_projects_id TYPE string,
lv_p_locations_id TYPE string,
lv_input_uri TYPE string,
lv_output_uri TYPE string,
ls_input TYPE /goog/cl_translation_v3=>ty_003,
lo_exception TYPE REF TO /goog/cx_sdk.
TRY.
"Open HTTP Connection
"Pass the configured client key - TRANSLATE_DEMO is used an example, replace it with actual value.
DATA(lo_translate) = NEW /goog/cl_translation_v3( iv_key_name = 'TRANSLATE_DEMO' ).
"Populate the data that needs to be passed to the api
"Derive project id
lv_p_projects_id = lo_translate->gv_project_id.
"Pass location id, us-central1 is used as an example, replace it with actual value.
lv_p_locations_id = 'us-central1'.
"Passing two target language codes (BCP-47 codes)
"TODO: Provide source and target cloud storage buckets, these follow the pattern: gs://<bucket_name>
"lv_input_uri =
"lv_output_uri =
"Values passed for source language code and target language codes are example, replace them with actual values.
ls_input = VALUE #( source_language_code = 'en-US'
target_language_codes = VALUE #( ( `es-ES` )
( `fr-FR` ) )
input_configs = VALUE #( ( gcs_source =
VALUE #( input_uri = lv_input_uri ) ) )
output_config = VALUE #( gcs_destination =
VALUE #( output_uri_prefix = lv_output_uri ) )
).
"Call the API
CALL METHOD lo_translate->batch_translate_document_lo
EXPORTING
iv_p_projects_id = lv_p_projects_id
iv_p_locations_id = lv_p_locations_id
is_input = ls_input
IMPORTING
es_output = DATA(ls_output)
ev_ret_code = DATA(lv_ret_code)
ev_err_text = DATA(lv_err_text)
es_err_resp = DATA(ls_err_resp).
IF /goog/cl_http_client=>is_success( lv_ret_code ).
"This returns a long running operation id for the job that is scheduled for glossary creation
"You can use the LRO ID to poll and check the status of the operation
WRITE: 'LRO ID:', ls_output-name.
ELSE.
MESSAGE lv_err_text TYPE 'E'.
ENDIF.
"Close HTTP Connection
lo_translate->close( ).
CATCH /goog/cx_sdk INTO lo_exception.
lv_err_text = lo_exception->get_text( ).
ENDTRY.