Referencia del grafo de Spanner para usuarios de openCypher

En este documento, se comparan openCypher y Spanner Graph en la siguiente tabla: maneras:

• Terminología
• Modelo de datos
• Esquema
• Consulta
• Mutación

En este documento, se asume que estás familiarizado openCypher v9.

Antes de comenzar

Configura y consulta Spanner Graph con la consola de Google Cloud.

Terminología

Cumplimiento de los estándares

Spanner Graph adopta las normas ISO Lenguaje de consulta de grafo (GQL) y Consultas de grafos de propiedades o SQL (SQL/PGQ).

Modelo de datos

Tanto Spanner Graph como openCypher adoptan el modelo de datos del grafo de propiedades con algunas diferencias.

Esquema

Consulta

Las capacidades de consulta de grafos de Spanner son similares a las de openCypher. Las diferencias entre el grafo de Spanner y openCypher se describen en esta sección.

Especifica el gráfico

En openCypher, hay un grafo predeterminado, y las consultas operan en esa plataforma. gráfico. En el grafo de Spanner, puedes definir más de un grafo y una consulta. debe comenzar con la cláusula GRAPH para especificar el gráfico que se consultará. Por ejemplo:

   GRAPH FinGraph
   MATCH (p:Person)
   RETURN p.name
   ORDER BY p.name
   LIMIT 1;

Para obtener más información, revisa la sintaxis de consulta de grafos.

Representar gráficamente la coincidencia de patrones

Spanner Graph admite capacidades de coincidencia de patrones de grafos similares a openCypher. Las diferencias se explican en las siguientes secciones.

Relación de unicidad y modo TRAIL

openCypher no devuelve resultados con aristas repetidas en una sola coincidencia; este se denomina unicidad de relaciones en openCypher. En el grafo de Spanner, los bordes repetidos se muestran de forma predeterminada. Si quieres que sea único, usa Modo TRAIL para garantizar que no exista ningún borde repetitivo en la sola coincidencia Para semántica detallada de TRAIL y otros modos de ruta de acceso diferentes, consulta Modo de ruta de acceso.

En el siguiente ejemplo, se muestra cómo cambian los resultados de una consulta con el modo TRAIL:

• Las consultas en modo TRAIL de grafo de openCypher y Spanner muestran un valor vacío porque la única ruta posible es repetir t1 dos veces.
• De forma predeterminada, la consulta de grafo de Spanner muestra una ruta válida.

MATCH
  (src:Account)-[t1:Transfers]->
  (dst:Account)-[t2:Transfers]->
  (src)-[t1]->(dst)
WHERE src.id = 16
RETURN src.id AS src_id, dst.id AS dst_id;
      

GRAPH FinGraph
MATCH TRAIL
  (src:Account)-[t1:Transfers]->
  (dst:Account)-[t2:Transfers]->
  (src)-[t1]->(dst)
WHERE src.id = 16
RETURN src.id AS src_id, dst.id AS dst_id;
      

GRAPH FinGraph
MATCH
  (src:Account)-[t1:Transfers]->
  (dst:Account)-[t2:Transfers]->
  (src)-[t1]-> (dst)
WHERE src.id = 16
RETURN src.id AS src_id, dst.id AS dst_id;
      

Cómo mostrar elementos del gráfico como resultados de la consulta

MATCH (account:Account)
WHERE account.id = 16;
RETURN account;

GRAPH FinGraph
MATCH (account:Account)
WHERE account.id = 16;
RETURN TO_JSON(account) AS account;

En el gráfico de Spanner, los resultados de la consulta no muestran elementos del gráfico. Usa el La función TO_JSON para mostrar elementos del gráfico como JSON.

Coincidencia de patrones de longitud variable y cuantificación de patrones

La coincidencia de patrones de longitud variable en openCypher se denomina cuantificación de ruta. en Spanner Graph. La cuantificación de la ruta de acceso usa una sintaxis diferente, como se muestra a continuación en el siguiente ejemplo. Para obtener más información, consulta Patrón de ruta cuantificada.

MATCH (src:Account)-[:Transfers*1..2]->(dst:Account)
WHERE src.id = 16
RETURN dst.id
ORDER BY dst.id;
     

GRAPH FinGraph
MATCH (src:Account)-[:Transfers]->{1,2}(dst:Account)
WHERE src.id = 16
RETURN dst.id
ORDER BY dst.id;
      

Patrón de longitud variable: lista de elementos

Spanner Graph te permite acceder directamente a las variables usadas en la ruta cuantificables. En el siguiente ejemplo, e en el grafo de Spanner es el mismo. como edges(p) en openCypher.

MATCH p=(src:Account)-[:Transfers*1..3]->(dst:Account)
WHERE src.id = 16
RETURN edges(p);
      

GRAPH FinGraph
MATCH (src:Account) -[e:Transfers]->{1,3} (dst:Account)
WHERE src.id = 16
RETURN TO_JSON(e) AS e;
     

El camino más corto

openCypher tiene dos funciones integradas para encontrar la ruta más corta entre nodos: shortestPath y allShortestPath.

• shortestPath encuentra una única ruta más corta entre nodos.
• allShortestPath busca todas las rutas más cortas entre nodos. Puede ser múltiples rutas de la misma longitud.

Spanner Graph usa una sintaxis diferente para encontrar una sola ruta más corta entre nodos: ANY SHORTEST para shortestPath. allShortestPath no es compatible.

MATCH
  (src:Account {id: 7}),
  (dst:Account {id: 20}),
  p = shortestPath((src)-[*1..10]->(dst))
RETURN length(p) AS path_length;
      

GRAPH FinGraph
MATCH ANY SHORTEST
  (src:Account {id: 7})-[e:Transfers]->{1, 3}
  (dst:Account {id: 20})
RETURN ARRAY_LENGTH(e) AS path_length;
      

Sentencias y cláusulas

En la siguiente tabla, se enumeran las cláusulas de openCypher y se indica si que son compatibles con Spanner Graph.

GRAPH FinGraph
MATCH (p:Person)
RETURN EXTRACT(YEAR FROM p.birthday) AS birthYear;

GRAPH FinGraph
MATCH (p:Person)
RETURN EXTRACT(YEAR FROM p.birthday); -- No aliasing

GRAPH FinGraph
MATCH (n:Account)
RETURN n.id
SKIP @offsetParameter
LIMIT 3;

GRAPH FinGraph
MATCH (n:Account)
RETURN n.id
LIMIT VALUE {
  MATCH (m:Person)
  RETURN COUNT(*) AS count
} AS count; -- Not a constant expression

GRAPH FinGraph
LET arr = [1, 2, 3]
FOR num IN arr
RETURN num;

Tipos de datos

Spanner Graph admite todos los tipos de datos de GoogleSQL. Para ver más información, consulta Tipos de datos en GoogleSQL.

En las siguientes secciones, se comparan los tipos de datos de openCypher con los datos del grafo de Spanner. de tipos de datos.

Tipo estructural

Tipo de propiedad

Tipo compuesto

Spanner Graph no admite listas heterogéneas de diferentes tipos o mapas de una lista de claves dinámicas y tipos de valores de elementos heterogéneos. Usa JSON para estos casos de uso.

Coerción de tipos

Para obtener más información sobre las reglas de conversión, consulte Reglas de conversión en GoogleSQL.

Funciones y expresiones

Además de las funciones y expresiones de grafos, Graph de Spanner admite todas las funciones y expresiones integradas de GoogleSQL.

Para obtener una lista completa de funciones y expresiones, consulta Operadores, condicionales y funciones de GoogleSQL.

En esta sección, se enumeran las funciones y expresiones de openCypher, así como su equivalentes en Spanner Graph.

Funciones y expresiones de tipos estructurales

MATCH (n)
RETURN n[n.name]

VALUE {
  MATCH pattern
  RETURN COUNT(*) AS count;
}

Funciones y expresiones de tipo de propiedad

a < b < c

      a < b AND b < C
      

      boolean_1 <> boolean_2
      

Otras expresiones

Parámetro de consulta

Las siguientes consultas muestran la diferencia entre usar parámetros en openCypher y en Spanner Graph.

MATCH (n:Person)
WHERE n.id = $id
RETURN n.name;

GRAPH FinGraph
MATCH (n:Person)
WHERE n.id = @id
RETURN n.name;

Mutación

Spanner Graph usa DML de GoogleSQL para mutar las tablas de entrada perimetral y de nodo. Para obtener más información, consulta Insertar, actualizar o borrar datos del gráfico de Spanner.

Crear nodo y perímetro

CREATE (:Person {id: 100, name: 'John'});
CREATE (:Account {id: 1000, is_blocked: FALSE});


MATCH (p:Person {id: 100}),
      (a:Account {id: 1000})
CREATE (p)-[:Owns {create_time: timestamp()}]->(a);

INSERT INTO
Person (id, name)
VALUES (100, "John");


INSERT INTO
Account (id, is_blocked)
VALUES (1000, FALSE);


INSERT INTO PersonOwnAccount (id, account_id, create_time)
VALUES (100, 1000, CURRENT_TIMESTAMP());

MATCH (a:Account {id: 1}), (oa:Account)
WHERE oa <> a
CREATE (a)-[:Transfers {amount: 100, create_time: timestamp()}]->(oa);

INSERT INTO AccountTransferAccount(id, to_id, create_time, amount)
SELECT a.id, oa.id, CURRENT_TIMESTAMP(), 100
FROM GRAPH_TABLE(
  FinGraph
  MATCH
    (a:Account {id:1000}),
    (oa:Account)
  WHERE oa <> a
);

En el grafo de Spanner, las etiquetas se asignan estáticamente según el CREATE PROPERTY GRAPH declaración DDL.

Actualiza el nodo y el perímetro

MATCH (p:Person {id: 100})
SET p.country = 'United States';

UPDATE Person AS p
SET p.country = 'United States'
WHERE p.id = 100;

Para actualizar etiquetas de gráficos de Spanner, consulta Crea, actualiza o descarta un esquema de grafo de Spanner.

Combinar nodo y perímetro

MERGE (p:Person {id: 100, country: 'United States'});

INSERT OR UPDATE INTO Person
(id, country)
VALUES (100, 'United States');

Borrar nodo y perímetro

Borrar aristas equivale a borrar la tabla de entrada.

MATCH (p:Person {id:100}), (a:Account {id:1000})
DELETE (p)-[:Owns]->(a);

DELETE PersonOwnAccount
WHERE id = 100 AND account_id = 1000;

Para borrar nodos, se deben controlar los posibles bordes colgantes. Cuando se especifica DELETE CASCADE, DELETE quita los bordes asociados de como DETACH DELETE en openCypher. Para obtener más información, consulta Spanner descripción general del esquema.

DETACH DELETE (:Account {id: 1000});

DELETE Account
WHERE id = 1000;

Muestra los resultados de mutación

MATCH (p:Person {id: 100})
SET p.country = 'United States'
RETURN p.id, p.name;

UPDATE Person AS p
SET p.country = 'United States'
WHERE p.id = 100
THEN RETURN id, name;

DELETE (p:Person {id: 100})
RETURN p.country;

DELETE FROM Person
WHERE id = 100
THEN RETURN country;

¿Qué sigue?

• Descripción general del gráfico de Spanner.