Dirección IP saliente estática

gcloud

1. Busca el nombre de tu red de VPC:

   gcloud compute networks list

   Deberías ver un resultado como el siguiente:

   NAME     SUBNET_MODE  BGP_ROUTING_MODE
   default  AUTO         REGIONAL

   Identifica la red que conectarás al conector de Acceso a VPC sin servidores.

2. Crea una subred en la VPC para el conector de acceso a VPC sin servidores.

   gcloud compute networks subnets create SUBNET_NAME \
   --range=RANGE --network=NETWORK_NAME --region=REGION

   Reemplaza los siguientes valores en este comando:

   • SUBNET_NAME por el nombre que deseas darle a la subred
   • RANGE con el rango de IP en formato CIDR que deseas asignar a esta subred (por ejemplo, 10.124.0.0/28).
   • NETWORK_NAME por el nombre de la red de VPC.
   • REGION por la región en la que deseas crear un conector de acceso a VPC sin servidores.

Terraform

1. Crea la red de VPC que se usará.

   resource "google_compute_network" "default" {
     name = "cr-static-ip-network"
   }

   Reemplaza cr-static-ip-network por el nombre de la subred.

2. Crea una subred en la VPC para el conector de acceso a VPC sin servidores.

   resource "google_compute_subnetwork" "default" {
     name          = "cr-static-ip"
     ip_cidr_range = "10.124.0.0/28"
     network       = google_compute_network.default.id
     region        = "us-central1"
   }

   Reemplaza lo siguiente:

   • cr-static-ip por el nombre de la subred
   • 10.124.0.0/28 por tu rango de CIDR.
   • us-central1 por tu región de Google Cloud.

gcloud

1. Crea un conector de acceso a VPC sin servidores con una subred creada con anterioridad.

   gcloud compute networks vpc-access connectors create CONNECTOR_NAME \
     --region=REGION \
     --subnet-project=PROJECT_ID \
     --subnet=SUBNET_NAME

   Reemplaza los siguientes valores en este comando:

   • CONNECTOR por el nombre que deseas asignar a este recurso.
   • PROJECT_ID por un nombre que aloje la subred.
   • SUBNET_NAME por el nombre de la subred que creaste.
   • REGION por la región en la que deseas crear una puerta de enlace de Cloud NAT

Terraform

1. Crea un conector de Acceso a VPC sin servidores.

   resource "google_project_service" "vpc" {
     service            = "vpcaccess.googleapis.com"
     disable_on_destroy = false
   }
   
   resource "google_vpc_access_connector" "default" {
     name          = "cr-conn"
     region        = "us-central1"
     min_instances = 2
     max_instances = 3
   
     subnet {
       name = google_compute_subnetwork.default.name
     }
   
     # Wait for VPC API enablement
     # before creating this resource
     depends_on = [
       google_project_service.vpc
     ]
   }

   Reemplaza cr-conn por el nombre de tu conector de Acceso a VPC sin servidores.

gcloud

1. Crea un Cloud Router nuevo para programar una puerta de enlace de Cloud NAT:

   gcloud compute routers create ROUTER_NAME \
     --network=NETWORK_NAME \
     --region=REGION

   Reemplaza los siguientes valores en este comando:

   • ROUTER_NAME por un nombre para el recurso de Cloud Router que deseas crear
   • NETWORK_NAME por el nombre de la red de VPC que encontraste antes.
   • REGION por la región en la que deseas crear una puerta de enlace de Cloud NAT

2. Reserva una dirección IP estática. Un recurso de dirección IP reservada retiene la dirección IP subyacente cuando el recurso al que está asociado se borra y se vuelve a crear:

   gcloud compute addresses create ORIGIN_IP_NAME --region=REGION

   Reemplaza los siguientes valores en este comando:

   • ORIGIN_IP_NAME por el nombre que deseas asignar al recurso de dirección IP
   • REGION por la región en la que se ejecutará el router de Cloud NAT. Usa la misma región que tu servicio de Cloud Run para minimizar la latencia y los costos de red.

3. Crea una configuración de puerta de enlace de Cloud NAT en este router para enrutar el tráfico que se origina desde la red de VPC mediante la dirección IP estática que creaste:

   gcloud compute routers nats create NAT_NAME \
     --router=ROUTER_NAME \
     --region=REGION \
     --nat-custom-subnet-ip-ranges=SUBNET_NAME \
     --nat-external-ip-pool=ORIGIN_IP_NAME

   Reemplaza los siguientes valores en este comando:

   • NAT_NAME por un nombre para el recurso de puerta de enlace de Cloud NAT que deseas crear
   • ROUTER_NAME por el nombre de tu Cloud Router
   • REGION por la región en la que deseas crear una puerta de enlace de Cloud NAT
   • SUBNET_NAME por el nombre de la subred
   • ORIGIN_IP_NAME por el nombre del recurso de dirección IP reservada que creaste en el paso anterior

Terraform

1. Crea un Cloud Router nuevo para programar una puerta de enlace de Cloud NAT:

   resource "google_compute_router" "default" {
     name    = "cr-static-ip-router"
     network = google_compute_network.default.name
     region  = google_compute_subnetwork.default.region
   }

   Reemplaza cr-static-ip-router por el nombre de la subred.

2. Reserva una dirección IP estática. Un recurso de dirección IP reservada retiene la dirección IP subyacente cuando el recurso al que está asociado se borra y se vuelve a crear:

   resource "google_compute_address" "default" {
     name   = "cr-static-ip-addr"
     region = google_compute_subnetwork.default.region
   }

   Reemplaza cr-static-ip-addr por el nombre de la subred.

3. Crea una configuración de puerta de enlace de Cloud NAT en este router para enrutar el tráfico que se origina desde la red de VPC mediante la dirección IP estática que creaste:

   resource "google_compute_router_nat" "default" {
     name   = "cr-static-nat"
     router = google_compute_router.default.name
     region = google_compute_subnetwork.default.region
   
     nat_ip_allocate_option = "MANUAL_ONLY"
     nat_ips                = [google_compute_address.default.self_link]
   
     source_subnetwork_ip_ranges_to_nat = "LIST_OF_SUBNETWORKS"
     subnetwork {
       name                    = google_compute_subnetwork.default.id
       source_ip_ranges_to_nat = ["ALL_IP_RANGES"]
     }
   }

   Reemplaza cr-static-nat por el nombre de la puerta de enlace de Cloud NAT.

gcloud

• Salida de VPC directa

  Para implementar o actualizar tu servicio de Cloud Run para usar la salida de VPC directa y enrutar todo el tráfico de salida a través de él, ejecuta el siguiente comando:

  gcloud run deploy SERVICE_NAME \
  --image=IMAGE_URL \
  --network=NETWORK \
  --subnet=SUBNET \
  --region=REGION \
  --vpc-egress=all-traffic

  Reemplaza los siguientes valores en este comando:

  • SERVICE_NAME por el nombre del servicio de Cloud Run que deseas implementar.
  • IMAGE_URL por una referencia a la imagen del contenedor, como us-docker.pkg.dev/cloudrun/container/hello:latest Si usas Artifact Registry, el repositorio REPO_NAME debe estar creado. La URL tiene el formato LOCATION-docker.pkg.dev/PROJECT_ID/REPO_NAME/PATH:TAG.
  • NETWORK por el nombre de la red de VPC.
  • SUBNET por el nombre de la subred
  • REGION por una región para el servicio.

• Conector de Acceso a VPC sin servidores

  Para implementar o actualizar tu servicio de Cloud Run para usar un conector de Acceso a VPC sin servidores y enrutar todo el tráfico de salida a través de él, ejecuta el siguiente comando:

  gcloud run deploy SERVICE_NAME \
  --image=IMAGE_URL \
  --vpc-connector=CONNECTOR_NAME \
  --region=REGION \
  --vpc-egress=all-traffic

  Reemplaza los siguientes valores en este comando:

  • SERVICE_NAME por el nombre del servicio de Cloud Run que deseas implementar.
  • IMAGE_URL por una referencia a la imagen del contenedor, como us-docker.pkg.dev/cloudrun/container/hello:latest Si usas Artifact Registry, el repositorio REPO_NAME debe estar creado. La URL tiene el formato LOCATION-docker.pkg.dev/PROJECT_ID/REPO_NAME/PATH:TAG.
  • CONNECTOR_NAME por el nombre de tu conector de Acceso a VPC sin servidores
  • REGION por una región para el servicio.

Terraform

Este servicio de Cloud Run usa un conector de VPC y enruta todo el tráfico de salida a través de él:

resource "google_cloud_run_v2_service" "default" {
  name     = "cr-static-ip-service"
  location = google_compute_subnetwork.default.region

  deletion_protection = false # set to "true" in production

  template {
    containers {
      # Replace with the URL of your container
      #   gcr.io/<YOUR_GCP_PROJECT_ID>/<YOUR_CONTAINER_NAME>
      image = "us-docker.pkg.dev/cloudrun/container/hello"
    }
    scaling {
      max_instance_count = 5
    }
    vpc_access {
      connector = google_vpc_access_connector.default.id
      egress    = "ALL_TRAFFIC"
    }
  }
  ingress = "INGRESS_TRAFFIC_ALL"

}

Reemplaza us-docker.pkg.dev/cloudrun/container/hello por una referencia a tu imagen de contenedor.