处理来自多个区域的流量

gcloud CLI

1. 预留静态 IP 地址，这样您就无需在重新创建负载平衡器时更新 DNS 记录。

   gcloud compute addresses create --global SERVICE_IP

   在上述命令中，将 SERVICE_IP 替换为 IP 地址资源的名称（例如 myservice-ip）。

   此 IP 地址是一个全球任播 IPv4 地址，可路由到 Google 数据中心或离访问者最近的接入点。

2. 创建后端服务。

   gcloud compute backend-services create --global BACKEND_NAME

   在上述命令中，将 BACKEND_NAME 替换为您要提供给后端服务的名称（例如 myservice-backend）。

3. 创建网址映射。

   gcloud compute url-maps create URLMAP_NAME --default-service=BACKEND_NAME

   将 URLMAP_NAME 替换为您要提供给网址映射的名称（例如 myservice-urlmap）。

4. 为您的网域创建代管式 TLS 证书，以处理 HTTPS 流量。（将 example.com 替换为您的域名。）

   gcloud compute ssl-certificates create CERT_NAME \
     --domains=example.com

   将 CERT_NAME 替换为您希望代管式 SSL 证书具有的名称（例如 myservice-cert）。

5. 创建一个目标 HTTPS 代理。

   gcloud compute target-https-proxies create HTTPS_PROXY_NAME \
     --ssl-certificates=CERT_NAME \
     --url-map=URLMAP_NAME

   将 HTTPS_PROXY_NAME 替换为您要提供给目标 HTTPS 代理的名称（例如 myservice-https）。

6. 创建一条转发规则，将您创建的网络资源连接到 IP 地址。

   gcloud compute forwarding-rules create --global FORWARDING_RULE_NAME \
     --target-https-proxy=HTTPS_PROXY_NAME \
     --address=SERVICE_IP \
     --ports=443

   将 FORWARDING_RULE_NAME 替换为您要创建的转发规则资源的名称（例如 myservice-lb）。

Terraform

除本部分介绍的步骤外，您还可以使用全球 HTTP 负载均衡器 Terraform 模块。

将以下内容添加到 Terraform 文件（例如 main.tf）中：

1. 配置 IP 地址：

   resource "google_compute_global_address" "lb_default" {
     provider = google-beta
     name     = "myservice-service-ip"
   
     # Use an explicit depends_on clause to wait until API is enabled
     depends_on = [
       google_project_service.compute_api
     ]
   }
   output "load_balancer_ip_addr" {
     value = google_compute_global_address.lb_default.address
   }

   将您的 IP 地址资源名称配置为 myservice-service-ip。您可以将此项更改为您自己的值。此 IP 地址是一个全球任播 IPv4 地址，可路由到 Google 数据中心或离访问者最近的入网点。

2. 创建和配置后端服务：

   resource "google_compute_backend_service" "lb_default" {
     provider              = google-beta
     name                  = "myservice-backend"
     load_balancing_scheme = "EXTERNAL_MANAGED"
   
     backend {
       group = google_compute_region_network_endpoint_group.lb_default[0].id
     }
   
     backend {
       group = google_compute_region_network_endpoint_group.lb_default[1].id
     }
   
     # Use an explicit depends_on clause to wait until API is enabled
     depends_on = [
       google_project_service.compute_api,
     ]
   }

   此资源将后端服务配置为名为 myservice-backend。您可以将此项更改为您自己的值。

3. 配置网址映射：

   resource "google_compute_url_map" "lb_default" {
     provider        = google-beta
     name            = "myservice-lb-urlmap"
     default_service = google_compute_backend_service.lb_default.id
   
     path_matcher {
       name            = "allpaths"
       default_service = google_compute_backend_service.lb_default.id
       route_rules {
         priority = 1
         url_redirect {
           https_redirect         = true
           redirect_response_code = "MOVED_PERMANENTLY_DEFAULT"
         }
       }
     }
   }

   将后端服务资源 (myservice-backend) 连接到新的网址映射资源 (myservice-lb-urlmap)。您可以将它们更改为您自己的值。

4. 为您的网域创建代管式 TLS 证书，以传送 HTTPS 流量。将 example.com 替换为 google_compute_managed_ssl_certificate 资源中的域名：

   resource "google_compute_managed_ssl_certificate" "lb_default" {
     provider = google-beta
     name     = "myservice-ssl-cert"
   
     managed {
       domains = ["example.com"]
     }
   }

5. 配置 HTTPS 代理：

   resource "google_compute_target_https_proxy" "lb_default" {
     provider = google-beta
     name     = "myservice-https-proxy"
     url_map  = google_compute_url_map.lb_default.id
     ssl_certificates = [
       google_compute_managed_ssl_certificate.lb_default.name
     ]
     depends_on = [
       google_compute_managed_ssl_certificate.lb_default
     ]
   }

   创建目标名称为 myservice-https-proxy 的 google_compute_target_https_proxy 资源，并连接先前创建的 TLS 证书 (myservice-ssl-cert) 和网址映射资源 (myservice-lb-urlmap)。您可以将它们更改为您自己的值。

6. 配置转发规则：

   resource "google_compute_global_forwarding_rule" "lb_default" {
     provider              = google-beta
     name                  = "myservice-lb-fr"
     load_balancing_scheme = "EXTERNAL_MANAGED"
     target                = google_compute_target_https_proxy.lb_default.id
     ip_address            = google_compute_global_address.lb_default.id
     port_range            = "443"
     depends_on            = [google_compute_target_https_proxy.lb_default]
   }

   创建目标名称为 myservice-https-proxy 的 google_compute_global_forwarding_rule 资源，并连接先前创建的 HTTPS 代理目标 (myservice-https-proxy) 和 IP 地址资源 (myservice-service-ip)。您可以将它们更改为您自己的值。

7. 应用此配置：

   如需在 Google Cloud 项目中应用 Terraform 配置，请完成以下部分中的步骤。

   准备 Cloud Shell

   1. 启动 Cloud Shell。

   2. 设置要在其中应用 Terraform 配置的默认 Google Cloud 项目。

      您只需为每个项目运行一次以下命令，即可在任何目录中运行它。

      export GOOGLE_CLOUD_PROJECT=PROJECT_ID

      如果您在 Terraform 配置文件中设置显式值，则环境变量会被替换。

   准备目录

   每个 Terraform 配置文件都必须有自己的目录（也称为“根模块”）。

   1. 在 Cloud Shell 中，创建一个目录，并在该目录中创建一个新文件。文件名必须具有 .tf 扩展名，例如 main.tf。在本教程中，该文件称为 main.tf。

      mkdir DIRECTORY && cd DIRECTORY && touch main.tf

   2. 如果您按照教程进行操作，可以在每个部分或步骤中复制示例代码。

      将示例代码复制到新创建的 main.tf 中。

      （可选）从 GitHub 中复制代码。如果端到端解决方案包含 Terraform 代码段，则建议这样做。

   3. 查看和修改要应用到您的环境的示例参数。
   4. 保存更改。
   5. 初始化 Terraform。您只需为每个目录执行一次此操作。

      terraform init

      （可选）如需使用最新的 Google 提供程序版本，请添加 -upgrade 选项：

      terraform init -upgrade

   应用更改

   1. 查看配置并验证 Terraform 将创建或更新的资源是否符合您的预期：

      terraform plan

      根据需要更正配置。

   2. 通过运行以下命令并在提示符处输入 yes 来应用 Terraform 配置：

      terraform apply

      等待 Terraform 显示“应用完成！”消息。

   3. 打开您的 Google Cloud 项目以查看结果。在 Google Cloud 控制台的界面中找到资源，以确保 Terraform 已创建或更新它们。

gcloud CLI

1. 在 REGION 中为 Cloud Run 服务创建网络端点组：

   gcloud compute network-endpoint-groups create NEG_NAME \
     --region=REGION \
     --network-endpoint-type=SERVERLESS \
     --cloud-run-service=SERVICE_NAME

   替换以下内容：

   • 将 NEG_NAME 替换为网络端点组资源的名称。 （例如“myservice-neg-uscentral1”）
   • 将 REGION 替换为部署服务的 [region][loc]。
   • 将 SERVICE_NAME 替换为您的服务名称。

2. 将网络端点组添加到后端服务：

   gcloud compute backend-services add-backend --global BACKEND_NAME \
     --network-endpoint-group-region=REGION \
     --network-endpoint-group=NEG_NAME

   指定您在上一步为该区域创建的 NEG_NAME。

3. 对每个区域重复上述步骤。

Terraform

1. 为在 run_regions 变量中指定的每个区域配置 Cloud Run 服务的网络端点组（名称为 myservice-neg）：

   resource "google_compute_region_network_endpoint_group" "lb_default" {
     provider              = google-beta
     count                 = length(local.run_regions)
     name                  = "myservice-neg"
     network_endpoint_type = "SERVERLESS"
     region                = local.run_regions[count.index]
     cloud_run {
       service = google_cloud_run_v2_service.run_default[count.index].name
     }
   }

2. 配置后端服务以连接网络端点组 (myservice-neg)：

   resource "google_compute_backend_service" "lb_default" {
     provider              = google-beta
     name                  = "myservice-backend"
     load_balancing_scheme = "EXTERNAL_MANAGED"
   
     backend {
       group = google_compute_region_network_endpoint_group.lb_default[0].id
     }
   
     backend {
       group = google_compute_region_network_endpoint_group.lb_default[1].id
     }
   
     # Use an explicit depends_on clause to wait until API is enabled
     depends_on = [
       google_project_service.compute_api,
     ]
   }

gcloud CLI

1. 使用重定向规则创建网址映射。

   gcloud compute url-maps import HTTP_URLMAP_NAME \
     --global \
     --source /dev/stdin <<EOF
           name: HTTP_URLMAP_NAME
           defaultUrlRedirect:
             redirectResponseCode: MOVED_PERMANENTLY_DEFAULT
             httpsRedirect: True
           EOF

   将 HTTP_URLMAP_NAME 替换为您创建的网址映射资源的名称（例如 myservice-httpredirect）。

2. 使用网址映射创建目标 HTTP 代理。

   gcloud compute target-http-proxies create HTTP_PROXY_NAME \
     --url-map=HTTP_URLMAP_NAME

   将 HTTP_PROXY_NAME 替换为您创建的目标 HTTP 代理的名称（例如 myservice-http）。

3. 在端口 80 上使用相同的预留 IP 地址创建转发规则。

   gcloud compute forwarding-rules create --global HTTP_FORWARDING_RULE_NAME \
     --target-http-proxy=HTTP_PROXY_NAME \
     --address=SERVICE_IP \
     --ports=80
           

   将 HTTP_FORWARDING_RULE_NAME 替换为您创建的新转发规则的名称（例如 myservice-httplb）。

Terraform

1. 使用重定向规则创建网址映射资源。

   resource "google_compute_url_map" "https_default" {
     provider = google-beta
     name     = "myservice-https-urlmap"
   
     default_url_redirect {
       redirect_response_code = "MOVED_PERMANENTLY_DEFAULT"
       https_redirect         = true
       strip_query            = false
     }
   }

2. 使用新创建的网址映射资源 (myservice-https-urlmap) 创建目标 HTTP 代理：

   resource "google_compute_target_http_proxy" "https_default" {
     provider = google-beta
     name     = "myservice-http-proxy"
     url_map  = google_compute_url_map.https_default.id
   
     depends_on = [
       google_compute_url_map.https_default
     ]
   }

3. 在端口 80 上使用相同的预留 IP 地址资源 (myservice-http-proxy) 创建转发规则。

   resource "google_compute_global_forwarding_rule" "https_default" {
     provider   = google-beta
     name       = "myservice-https-fr"
     target     = google_compute_target_http_proxy.https_default.id
     ip_address = google_compute_global_address.lb_default.id
     port_range = "80"
     depends_on = [google_compute_target_http_proxy.https_default]
   }