複数のリージョンからのトラフィックを処理する

gcloud CLI

1. 静的 IP アドレスを予約することにより、ロードバランサを再作成するときに DNS レコードを更新する必要がなくなります。

   gcloud compute addresses create --global SERVICE_IP

   上記のコマンドの SERVICE_IP は、IP アドレス リソースの名前（myservice-ip など）に置き換えます。

   この IP アドレスは、訪問者に最も近い Google データセンターまたはポイント オブ プレゼンスにルーティングするグローバル エニーキャスト IPv4 アドレスです。

2. バックエンド サービスを作成します。

   gcloud compute backend-services create --global BACKEND_NAME

   上記のコマンドで、BACKEND_NAME をバックエンド サービスに付ける名前（myservice-backend など）に置き換えます。

3. URL マップを作成します。

   gcloud compute url-maps create URLMAP_NAME --default-service=BACKEND_NAME

   URLMAP_NAME は、URL マップに付ける名前（myservice-urlmap など）に置き換えます。

4. HTTPS トラフィックを処理するために、ドメインのマネージド TLS 証明書を作成します。example.com はドメイン名で置き換えます。

   gcloud compute ssl-certificates create CERT_NAME \
     --domains=example.com

   CERT_NAME は、マネージド SSL 証明書に付ける名前（myservice-cert など）に置き換えます。

5. ターゲット HTTPS プロキシを作成します。

   gcloud compute target-https-proxies create HTTPS_PROXY_NAME \
     --ssl-certificates=CERT_NAME \
     --url-map=URLMAP_NAME

   HTTPS_PROXY_NAME は、ターゲット HTTPS プロキシに付ける名前（myservice-https など）に置き換えます。

6. 作成したネットワーク リソースを IP アドレスに接続する転送ルールを作成します。

   gcloud compute forwarding-rules create --global FORWARDING_RULE_NAME \
     --target-https-proxy=HTTPS_PROXY_NAME \
     --address=SERVICE_IP \
     --ports=443

   FORWARDING_RULE_NAME は、作成する転送ルールのリソースの名前（myservice-lb など）に置き換えます。

Terraform

このセクションで説明する手順の代わりに、グローバル HTTP ロードバランサの Terraform モジュールを使用することもできます。

Terraform ファイル（たとえば main.tf）に以下を追加します。

1. IP アドレスを構成します。

   resource "google_compute_global_address" "lb_default" {
     provider = google-beta
     name     = "myservice-service-ip"
   
     # Use an explicit depends_on clause to wait until API is enabled
     depends_on = [
       google_project_service.compute_api
     ]
   }
   output "load_balancer_ip_addr" {
     value = google_compute_global_address.lb_default.address
   }

   IP アドレス リソース名を myservice-service-ip に構成します。この値は独自の値に変更できます。この IP アドレスは、訪問者に最も近い Google データセンターまたはポイント オブ プレゼンスにルーティングするグローバル エニーキャスト IPv4 アドレスです。

2. バックエンド サービスを作成して構成します。

   resource "google_compute_backend_service" "lb_default" {
     provider              = google-beta
     name                  = "myservice-backend"
     load_balancing_scheme = "EXTERNAL_MANAGED"
   
     backend {
       group = google_compute_region_network_endpoint_group.lb_default[0].id
     }
   
     backend {
       group = google_compute_region_network_endpoint_group.lb_default[1].id
     }
   
     # Use an explicit depends_on clause to wait until API is enabled
     depends_on = [
       google_project_service.compute_api,
     ]
   }

   このリソースは、バックエンド サービスを myservice-backend という名前で構成します。この値は独自の値に変更できます。

3. URL マップを構成します。

   resource "google_compute_url_map" "lb_default" {
     provider        = google-beta
     name            = "myservice-lb-urlmap"
     default_service = google_compute_backend_service.lb_default.id
   
     path_matcher {
       name            = "allpaths"
       default_service = google_compute_backend_service.lb_default.id
       route_rules {
         priority = 1
         url_redirect {
           https_redirect         = true
           redirect_response_code = "MOVED_PERMANENTLY_DEFAULT"
         }
       }
     }
   }

   バックエンド サービス リソース（myservice-backend）を新しい URL マップリソース（myservice-lb-urlmap）に接続します。これらの値は、独自の値に変更できます。

4. HTTPS トラフィックを処理するために、ドメインのマネージド TLS 証明書を作成します。example.com は、google_compute_managed_ssl_certificate リソースのドメイン名に置き換えます。

   resource "google_compute_managed_ssl_certificate" "lb_default" {
     provider = google-beta
     name     = "myservice-ssl-cert"
   
     managed {
       domains = ["example.com"]
     }
   }

5. HTTPS プロキシを構成します。

   resource "google_compute_target_https_proxy" "lb_default" {
     provider = google-beta
     name     = "myservice-https-proxy"
     url_map  = google_compute_url_map.lb_default.id
     ssl_certificates = [
       google_compute_managed_ssl_certificate.lb_default.name
     ]
     depends_on = [
       google_compute_managed_ssl_certificate.lb_default
     ]
   }

   ターゲット名 myservice-https-proxy を使用して google_compute_target_https_proxy リソースを作成し、以前に作成した TLS 証明書（myservice-ssl-cert）と URL マッピング リソース（myservice-lb-urlmap）を接続します。これらの値は、独自の値に変更できます。

6. 転送ルールを構成します。

   resource "google_compute_global_forwarding_rule" "lb_default" {
     provider              = google-beta
     name                  = "myservice-lb-fr"
     load_balancing_scheme = "EXTERNAL_MANAGED"
     target                = google_compute_target_https_proxy.lb_default.id
     ip_address            = google_compute_global_address.lb_default.id
     port_range            = "443"
     depends_on            = [google_compute_target_https_proxy.lb_default]
   }

   ターゲット名 myservice-https-proxy を使用して google_compute_global_forwarding_rule リソースを作成し、以前に作成した HTTPS プロキシ ターゲット（myservice-https-proxy）と IP アドレス リソース（myservice-service-ip）を接続します。これらの値は、独自の値に変更できます。

7. この構成を適用します。

   Google Cloud プロジェクトで Terraform 構成を適用するには、次のセクションの手順を完了します。

   Cloud Shell を準備する

   1. Cloud Shell を起動します。

   2. Terraform 構成を適用するデフォルトの Google Cloud プロジェクトを設定します。

      このコマンドは、プロジェクトごとに 1 回だけ実行する必要があります。これは任意のディレクトリで実行できます。

      export GOOGLE_CLOUD_PROJECT=PROJECT_ID

      Terraform 構成ファイルに明示的な値を設定すると、環境変数がオーバーライドされます。

   ディレクトリを準備する

   Terraform 構成ファイルには独自のディレクトリ（ルート モジュールとも呼ばれます）が必要です。

   1. Cloud Shell で、ディレクトリを作成し、そのディレクトリ内に新しいファイルを作成します。ファイルの拡張子は .tf にする必要があります（例: main.tf）。このチュートリアルでは、このファイルを main.tf とします。

      mkdir DIRECTORY && cd DIRECTORY && touch main.tf

   2. チュートリアルを使用している場合は、各セクションまたはステップのサンプルコードをコピーできます。

      新しく作成した main.tf にサンプルコードをコピーします。

      必要に応じて、GitHub からコードをコピーします。Terraform スニペットがエンドツーエンドのソリューションの一部である場合は、この方法をおすすめします。

   3. 環境に適用するサンプル パラメータを確認し、変更します。
   4. 変更を保存します。
   5. Terraform を初期化します。これは、ディレクトリごとに 1 回だけ行う必要があります。

      terraform init

      必要に応じて、最新バージョンの Google プロバイダを使用する場合は、-upgrade オプションを使用します。

      terraform init -upgrade

   変更を適用する

   1. 構成を確認して、Terraform が作成または更新するリソースが想定どおりであることを確認します。

      terraform plan

      必要に応じて構成を修正します。

   2. 次のコマンドを実行し、プロンプトで「yes」と入力して、Terraform 構成を適用します。

      terraform apply

      Terraform に「Apply complete!」のメッセージが表示されるまで待ちます。

   3. Google Cloud プロジェクトを開いて結果を表示します。Google Cloud コンソールの UI でリソースに移動して、Terraform によって作成または更新されたことを確認します。

gcloud CLI

1. REGION に、Cloud Run サービスのネットワーク エンドポイント グループを作成します。

   gcloud compute network-endpoint-groups create NEG_NAME \
     --region=REGION \
     --network-endpoint-type=SERVERLESS \
     --cloud-run-service=SERVICE_NAME

   次のように置き換えます。

   • NEG_NAME は、ネットワーク エンドポイント グループ リソースの名前に置き換えます。 （例: 「myservice-neg-uscentral1」）
   • REGION: サービスがデプロイされている [region][loc]。
   • SERVICE_NAME: 実際のサービスの名前。

2. ネットワーク エンドポイント グループをバックエンド サービスに追加します。

   gcloud compute backend-services add-backend --global BACKEND_NAME \
     --network-endpoint-group-region=REGION \
     --network-endpoint-group=NEG_NAME

   前の手順で作成した NEG_NAME をリージョンに指定します。

3. リージョンごとに上記の手順を繰り返します。

Terraform

1. run_regions 変数で指定された各リージョンの Cloud Run サービス用に、名前が myservice-neg のネットワーク エンドポイント グループを構成します。

   resource "google_compute_region_network_endpoint_group" "lb_default" {
     provider              = google-beta
     count                 = length(local.run_regions)
     name                  = "myservice-neg"
     network_endpoint_type = "SERVERLESS"
     region                = local.run_regions[count.index]
     cloud_run {
       service = google_cloud_run_v2_service.run_default[count.index].name
     }
   }

2. ネットワーク エンドポイント グループ（myservice-neg）を接続するようにバックエンド サービスを構成します。

   resource "google_compute_backend_service" "lb_default" {
     provider              = google-beta
     name                  = "myservice-backend"
     load_balancing_scheme = "EXTERNAL_MANAGED"
   
     backend {
       group = google_compute_region_network_endpoint_group.lb_default[0].id
     }
   
     backend {
       group = google_compute_region_network_endpoint_group.lb_default[1].id
     }
   
     # Use an explicit depends_on clause to wait until API is enabled
     depends_on = [
       google_project_service.compute_api,
     ]
   }

gcloud CLI

1. リダイレクト ルールで URL マップを作成します。

   gcloud compute url-maps import HTTP_URLMAP_NAME \
     --global \
     --source /dev/stdin <<EOF
           name: HTTP_URLMAP_NAME
           defaultUrlRedirect:
             redirectResponseCode: MOVED_PERMANENTLY_DEFAULT
             httpsRedirect: True
           EOF

   HTTP_URLMAP_NAME は、作成する URL マップリソースの名前（myservice-httpredirect など）で置き換えます。

2. URL マップを使用してターゲット HTTP プロキシを作成します。

   gcloud compute target-http-proxies create HTTP_PROXY_NAME \
     --url-map=HTTP_URLMAP_NAME

   HTTP_PROXY_NAME は、作成するターゲット HTTP プロキシの名前（myservice-http など）に置き換えます。

3. 同じ予約済み IP アドレスのポート 80 での転送ルールを作成します。

   gcloud compute forwarding-rules create --global HTTP_FORWARDING_RULE_NAME \
     --target-http-proxy=HTTP_PROXY_NAME \
     --address=SERVICE_IP \
     --ports=80
           

   HTTP_FORWARDING_RULE_NAME は、作成する新しい転送ルールの名前（myservice-httplb など）で置き換えます。

Terraform

1. リダイレクト ルールで URL マップリソースを作成します。

   resource "google_compute_url_map" "https_default" {
     provider = google-beta
     name     = "myservice-https-urlmap"
   
     default_url_redirect {
       redirect_response_code = "MOVED_PERMANENTLY_DEFAULT"
       https_redirect         = true
       strip_query            = false
     }
   }

2. 新しく作成した URL マップリソース（myservice-https-urlmap）を使用して、ターゲット HTTP プロキシを作成します。

   resource "google_compute_target_http_proxy" "https_default" {
     provider = google-beta
     name     = "myservice-http-proxy"
     url_map  = google_compute_url_map.https_default.id
   
     depends_on = [
       google_compute_url_map.https_default
     ]
   }

3. 同じ予約済み IP アドレス リソース（myservice-http-proxy）のポート 80 での転送ルールを作成します。

   resource "google_compute_global_forwarding_rule" "https_default" {
     provider   = google-beta
     name       = "myservice-https-fr"
     target     = google_compute_target_http_proxy.https_default.id
     ip_address = google_compute_global_address.lb_default.id
     port_range = "80"
     depends_on = [google_compute_target_http_proxy.https_default]
   }