静的なアウトバウンド IP アドレス

gcloud

1. VPC ネットワークの名前を確認します。

   gcloud compute networks list

   次のような出力が表示されます。

   NAME     SUBNET_MODE  BGP_ROUTING_MODE
   default  AUTO         REGIONAL

   サーバーレス VPC アクセス コネクタに接続するネットワークを特定します。

2. サーバーレス VPC アクセス コネクタ用の VPC にサブネットを作成します。

   gcloud compute networks subnets create SUBNET_NAME \
   --range=RANGE --network=NETWORK_NAME --region=REGION

   このコマンドで次の値を置き換えます。

   • SUBNET_NAME は、サブネットに付ける名前に置き換えます。
   • RANGE は、このサブネットに割り当てる CIDR 形式の IP 範囲（10.124.0.0/28 など）に置き換えます。
   • NETWORK_NAME は VPC ネットワークの名前に置き換えます。
   • REGION は、サーバーレス VPC アクセス コネクタを作成するリージョンに置き換えます。

Terraform

1. 使用する VPC ネットワークを作成します。

   resource "google_compute_network" "default" {
     name = "cr-static-ip-network"
   }

   cr-static-ip-network は、サブネット名に置き換えます。

2. サーバーレス VPC アクセス コネクタ用の VPC にサブネットを作成します。

   resource "google_compute_subnetwork" "default" {
     name          = "cr-static-ip"
     ip_cidr_range = "10.124.0.0/28"
     network       = google_compute_network.default.id
     region        = "us-central1"
   }

   次のように置き換えます。

   • cr-static-ip は、サブネット名に置き換えます。
   • 10.124.0.0/28 は、CIDR 範囲に置き換えます。
   • us-central1 は、Google Cloud リージョンに置き換えます。

gcloud

1. 事前に作成されたサブネットでサーバーレス VPC アクセス コネクタを作成します。

   gcloud compute networks vpc-access connectors create CONNECTOR_NAME \
     --region=REGION \
     --subnet-project=PROJECT_ID \
     --subnet=SUBNET_NAME

   このコマンドで次の値を置き換えます。

   • CONNECTOR は、このリソースに付ける名前に置き換えます。
   • PROJECT_ID は、サブネットをホストする名前に置き換えます。
   • SUBNET_NAME は、作成したサブネットの名前に置き換えます。
   • REGION は、Cloud NAT ゲートウェイを作成するリージョンに置き換えます。

Terraform

1. サーバーレス VPC アクセス コネクタを作成します。

   resource "google_project_service" "vpc" {
     service            = "vpcaccess.googleapis.com"
     disable_on_destroy = false
   }
   
   resource "google_vpc_access_connector" "default" {
     name          = "cr-conn"
     region        = "us-central1"
     min_instances = 2
     max_instances = 3
   
     subnet {
       name = google_compute_subnetwork.default.name
     }
   
     # Wait for VPC API enablement
     # before creating this resource
     depends_on = [
       google_project_service.vpc
     ]
   }

   cr-conn は、サーバーレス VPC アクセス コネクタの名前に置き換えます。

gcloud

1. Cloud NAT ゲートウェイをプログラムする新しい Cloud Router を作成します。

   gcloud compute routers create ROUTER_NAME \
     --network=NETWORK_NAME \
     --region=REGION

   このコマンドで次の値を置き換えます。

   • ROUTER_NAME は、作成する Cloud Router リソースの名前に置き換えます。
   • NETWORK_NAME は、先ほど確認した VPC ネットワークの名前に置き換えます。
   • REGION は、Cloud NAT ゲートウェイを作成するリージョンに置き換えます。

2. 静的 IP アドレスを予約します。予約済み IP アドレス リソースは、関連付けられているリソースが削除されて再作成されるときに、元の IP アドレスを保持します。

   gcloud compute addresses create ORIGIN_IP_NAME --region=REGION

   このコマンドで次の値を置き換えます。

   • ORIGIN_IP_NAME は、IP アドレス リソースに割り当てる名前で置き換えます。
   • REGION は、Cloud NAT ルーターを実行するリージョンに置き換えます。レイテンシとネットワーク コストを最小限に抑えるには、Cloud Run サービスと同じリージョンを使用します。

3. 作成した静的 IP アドレスを使用して VPC ネットワークからのトラフィックをルーティングするように、このルーターに Cloud NAT ゲートウェイの構成を作成します。

   gcloud compute routers nats create NAT_NAME \
     --router=ROUTER_NAME \
     --region=REGION \
     --nat-custom-subnet-ip-ranges=SUBNET_NAME \
     --nat-external-ip-pool=ORIGIN_IP_NAME

   このコマンドで次の値を置き換えます。

   • NAT_NAME は、作成する Cloud NAT ゲートウェイ リソースの名前に置き換えます。
   • ROUTER_NAME は、Cloud Router の名前に置き換えます。
   • REGION は、Cloud NAT ゲートウェイを作成するリージョンに置き換えます。
   • SUBNET_NAME: サブネットの名前。
   • ORIGIN_IP_NAME は、前の手順で作成した予約済み IP アドレス リソースの名前に置き換えます。

Terraform

1. Cloud NAT ゲートウェイをプログラムする新しい Cloud Router を作成します。

   resource "google_compute_router" "default" {
     name    = "cr-static-ip-router"
     network = google_compute_network.default.name
     region  = google_compute_subnetwork.default.region
   }

   cr-static-ip-router は、使用するサブネット名に置き換えます。

2. 静的 IP アドレスを予約します。予約済み IP アドレス リソースは、関連付けられているリソースが削除されて再作成されるときに、元の IP アドレスを保持します。

   resource "google_compute_address" "default" {
     name   = "cr-static-ip-addr"
     region = google_compute_subnetwork.default.region
   }

   cr-static-ip-addr は、使用するサブネット名に置き換えます。

3. 作成した静的 IP アドレスを使用して VPC ネットワークからのトラフィックをルーティングするように、このルーターに Cloud NAT ゲートウェイの構成を作成します。

   resource "google_compute_router_nat" "default" {
     name   = "cr-static-nat"
     router = google_compute_router.default.name
     region = google_compute_subnetwork.default.region
   
     nat_ip_allocate_option = "MANUAL_ONLY"
     nat_ips                = [google_compute_address.default.self_link]
   
     source_subnetwork_ip_ranges_to_nat = "LIST_OF_SUBNETWORKS"
     subnetwork {
       name                    = google_compute_subnetwork.default.id
       source_ip_ranges_to_nat = ["ALL_IP_RANGES"]
     }
   }

   cr-static-nat は、Cloud NAT ゲートウェイ名に置き換えます。

gcloud

• ダイレクト VPC 下り（外向き）

  ダイレクト VPC 下り（外向き）を使用してすべての下り（外向き）トラフィックを転送する Cloud Run サービスをデプロイまたは更新するには、次のコマンドを実行します。

  gcloud run deploy SERVICE_NAME \
  --image=IMAGE_URL \
  --network=NETWORK \
  --subnet=SUBNET \
  --region=REGION \
  --vpc-egress=all-traffic

  このコマンドで次の値を置き換えます。

  • SERVICE_NAME は、デプロイする Cloud Run サービスの名前に置き換えます。
  • IMAGE_URL は、コンテナ イメージへの参照（us-docker.pkg.dev/cloudrun/container/hello:latest など）に置き換えます。Artifact Registry を使用する場合は、リポジトリ REPO_NAME がすでに作成されている必要があります。URL の形式は LOCATION-docker.pkg.dev/PROJECT_ID/REPO_NAME/PATH:TAG です。
  • NETWORK: VPC ネットワークの名前。
  • SUBNET: サブネットの名前。
  • REGION: サービスのリージョン。

• サーバーレス VPC アクセス コネクタ

  サーバーレス VPC アクセス コネクタを使用してすべての下り（外向き）トラフィックを転送する Cloud Run サービスをデプロイまたは更新するには、次のコマンドを実行します。

  gcloud run deploy SERVICE_NAME \
  --image=IMAGE_URL \
  --vpc-connector=CONNECTOR_NAME \
  --region=REGION \
  --vpc-egress=all-traffic

  このコマンドで次の値を置き換えます。

  • SERVICE_NAME は、デプロイする Cloud Run サービスの名前に置き換えます。
  • IMAGE_URL は、コンテナ イメージへの参照（us-docker.pkg.dev/cloudrun/container/hello:latest など）に置き換えます。Artifact Registry を使用する場合は、リポジトリ REPO_NAME がすでに作成されている必要があります。URL の形式は LOCATION-docker.pkg.dev/PROJECT_ID/REPO_NAME/PATH:TAG です。
  • CONNECTOR_NAME は、サーバーレス VPC アクセス コネクタの名前に置き換えます。
  • REGION: サービスのリージョン。

Terraform

この Cloud Run サービスは、VPC コネクタを使用してすべての下り（外向き）トラフィックをルーティングします。

resource "google_cloud_run_v2_service" "default" {
  name     = "cr-static-ip-service"
  location = google_compute_subnetwork.default.region

  deletion_protection = false # set to "true" in production

  template {
    containers {
      # Replace with the URL of your container
      #   gcr.io/<YOUR_GCP_PROJECT_ID>/<YOUR_CONTAINER_NAME>
      image = "us-docker.pkg.dev/cloudrun/container/hello"
    }
    scaling {
      max_instance_count = 5
    }
    vpc_access {
      connector = google_vpc_access_connector.default.id
      egress    = "ALL_TRAFFIC"
    }
  }
  ingress = "INGRESS_TRAFFIC_ALL"

}

us-docker.pkg.dev/cloudrun/container/hello は、コンテナ イメージへの参照に置き換えます。