Membuat alur kerja menggunakan Terraform

Membuat file konfigurasi Terraform

Buat file konfigurasi Terraform bernama main.tf dan sertakan resource Penyedia Google untuk Terraform yang digunakan dalam panduan memulai ini.

Perhatikan bahwa Anda dapat menggunakan interpolasi untuk substitusi seperti variabel referensi, atribut resource, dan fungsi panggilan.

1. Buat direktori:

   mkdir terraform

2. Buka direktori terraform:

   cd terraform

3. Tambahkan file baru, main.tf, ke direktori:

   nano main.tf

4. Tambahkan resource berikut ke file main.tf:

   1. Tetapkan ID project:

      provider "google" {
      project = "PROJECT_ID"
      }

      Ganti PROJECT_ID dengan ID project Anda.

   2. Aktifkan Workflows API:

      # Enable Workflows API
      resource "google_project_service" "default" {
        service            = "workflows.googleapis.com"
        disable_on_destroy = false
      }

   3. Buat akun layanan untuk alur kerja:

      # Create a dedicated service account
      resource "google_service_account" "default" {
        account_id   = "sample-workflows-sa"
        display_name = "Sample Workflows Service Account"
      }

   4. Tentukan alur kerja menggunakan resource google_workflows_workflow:

      # Create a workflow
      resource "google_workflows_workflow" "default" {
        name            = "sample-workflow"
        region          = "us-central1"
        description     = "A sample workflow"
        service_account = google_service_account.default.id
        labels = {
          env = "test"
        }
        user_env_vars = {
          url = "https://timeapi.io/api/Time/current/zone?timeZone=Europe/Amsterdam"
        }
        source_contents = <<-EOF
        # This is a sample workflow that you can replace with your source code
        #
        # The workflow does the following:
        # - Retrieves the current date from a public API and stores the
        #   response in `currentDate`
        # - Retrieves a list of Wikipedia articles from a public API related
        #   to the day of the week stored in `currentDate`
        # - Returns the list of articles in the workflow output
        #
        # Note that when you define workflows in Terraform, variables must be
        # escaped with two dollar signs ($$) and not a single sign ($)
      
        - getCurrentDate:
            call: http.get
            args:
                url: $${sys.get_env("url")}
            result: currentDate
        - readWikipedia:
            call: http.get
            args:
                url: https://en.wikipedia.org/w/api.php
                query:
                    action: opensearch
                    search: $${currentDate.body.dayOfWeek}
            result: wikiResult
        - returnOutput:
            return: $${wikiResult.body[1]}
      EOF
      
        depends_on = [google_project_service.default]
      }

      Argumen berikut digunakan dalam contoh alur kerja:

      • name: nama alur kerja Anda.
      • region: lokasi alur kerja Anda.
      • description: deskripsi alur kerja Anda.
      • service_account: alamat email atau ID unik akun layanan yang terkait dengan versi alur kerja terbaru. Akun layanan ini merepresentasikan identitas alur kerja dan menentukan izin yang dimiliki alur kerja tersebut. Jika Anda tidak menentukan akun layanan selama pembuatan alur kerja, alur kerja tersebut akan menggunakan akun layanan Compute Engine default untuk identitasnya. Untuk mengetahui informasi selengkapnya, lihat bagian Memberikan izin alur kerja untuk mengakses resource Google Cloud.
      • labels: daftar pasangan label nilai kunci yang akan ditetapkan ke alur kerja ini yang membantu Anda mengatur instance Google Cloud. Untuk mengetahui informasi selengkapnya, lihat Apa yang dimaksud dengan label?
      • user_env_vars: variabel lingkungan buatan pengguna yang terkait dengan revisi alur kerja ini. Untuk mengetahui informasi selengkapnya, lihat Menggunakan variabel lingkungan.
      • source_contents: kode Workflows yang akan dieksekusi. Untuk batas ukuran file, lihat Batas resource.

      Argumen opsional lainnya meliputi:

      • crypto_key_name: ID resource untuk kunci Cloud Key Management Service dalam format berikut:

        projects/PROJECT_NAME/locations/LOCATION/keyRings/KEY_RING/cryptoKeys/KEY_NAME

        Untuk informasi selengkapnya, lihat Menggunakan kunci enkripsi yang dikelola pelanggan.

      • call_log_level: level logging yang akan diterapkan pada panggilan dan respons panggilan selama eksekusi alur kerja ini. Nilainya dapat berupa:

        • CALL_LOG_LEVEL_UNSPECIFIED
        • LOG_ALL_CALLS
        • LOG_ERRORS_ONLY
        • LOG_NONE

        Untuk mengetahui informasi lebih lanjut, lihat Logging panggilan.

      • project: ID project tempat resource berada. Jika tidak disediakan, project penyedia akan digunakan.

      • name_prefix: membuat nama unik yang dimulai dengan awalan yang ditentukan. Jika atribut ini dan name tidak ditentukan, nilai acak akan dipilih untuk nama tersebut.

Membuat dan menjalankan alur kerja

Deploy resource Terraform Anda untuk membuat alur kerja, lalu menjalankan alur kerja tersebut.

1. Lakukan inisialisasi Terraform di direktori:

   terraform init

2. Pastikan perubahan yang Anda usulkan dengan Terraform sesuai dengan rencana yang diharapkan:

   terraform plan

   Anda dapat mengabaikan catatan tentang tidak menggunakan opsi -out.

3. Buat alur kerja:

   terraform apply

4. Pada perintah Enter a value, ketik yes untuk melanjutkan pembuatan resource.

5. Pastikan alur kerja dibuat:

   gcloud workflows list --location us-central1

   Outputnya akan mirip dengan berikut ini:

   NAME                                                                    STATE   REVISION_ID  UPDATE_TIME
   projects/project-name/locations/us-central1/workflows/sample-workflow   ACTIVE  000001-f9a   2024-02-24T13:38:58.353765906Z

6. Secara opsional, Anda dapat menjalankan alur kerja:

   gcloud workflows execute sample-workflow