Creare un flusso di lavoro utilizzando Terraform

Questa guida rapida illustra come creare, eseguire il deployment ed eseguire il tuo primo flusso di lavoro utilizzando Terraform. Terraform è uno strumento Infrastructure as Code che consente di creare, modificare e migliorare in modo prevedibile l'infrastruttura cloud utilizzando il codice. Scopri come utilizzare Terraform per eseguire il provisioning dell'infrastruttura su Google Cloud.

In questa guida rapida, il flusso di lavoro di esempio invia una richiesta a un'API pubblica e poi restituisce la risposta dell'API.

Dovrai completare i seguenti passaggi:

  1. Abilita l'API Workflows utilizzando Terraform.
  2. Crea un account di servizio per il flusso di lavoro utilizzando Terraform.
  3. Definisci ed esegui il deployment di un flusso di lavoro utilizzando Terraform.
  4. Esegui il flusso di lavoro utilizzando Google Cloud CLI.

Prima di iniziare

I vincoli di sicurezza definiti dalla tua organizzazione potrebbero impedirti di completare i passaggi seguenti. Per informazioni sulla risoluzione dei problemi, vedi Sviluppare applicazioni in un ambiente Google Cloud vincolato.

Tieni presente che Terraform è già integrato in Cloud Shell. Se devi installare Terraform, consulta la documentazione di HashiCorp Terraform.

  1. Sign in to your Google Cloud account. If you're new to Google Cloud, create an account to evaluate how our products perform in real-world scenarios. New customers also get $300 in free credits to run, test, and deploy workloads.
  2. Install the Google Cloud CLI.

  3. To initialize the gcloud CLI, run the following command: 

    gcloud init

  4. Create or select a Google Cloud project.

    • Create a Google Cloud project:

      gcloud projects create PROJECT_ID

      Replace PROJECT_ID with a name for the Google Cloud project you are creating.

    • Select the Google Cloud project that you created:

      gcloud config set project PROJECT_ID

      Replace PROJECT_ID with your Google Cloud project name.

  5. Make sure that billing is enabled for your Google Cloud project.

  6. Enable the Cloud Resource Manager and Identity and Access Management (IAM) APIs: 

    gcloud services enable cloudresourcemanager.googleapis.com iam.googleapis.com
  7. Install the Google Cloud CLI.

  8. To initialize the gcloud CLI, run the following command: 

    gcloud init

  9. Create or select a Google Cloud project.

    • Create a Google Cloud project:

      gcloud projects create PROJECT_ID

      Replace PROJECT_ID with a name for the Google Cloud project you are creating.

    • Select the Google Cloud project that you created:

      gcloud config set project PROJECT_ID

      Replace PROJECT_ID with your Google Cloud project name.

  10. Make sure that billing is enabled for your Google Cloud project.

  11. Enable the Cloud Resource Manager and Identity and Access Management (IAM) APIs: 

    gcloud services enable cloudresourcemanager.googleapis.com iam.googleapis.com

Crea un file di configurazione Terraform

Crea un file di configurazione Terraform denominato main.tf e includi le risorse del provider Google per Terraform utilizzate in questo Quickstart.

Tieni presente che puoi utilizzare l'interpolazione per le sostituzioni, come le variabili di riferimento, gli attributi delle risorse e le funzioni di chiamata.

  1. Crea una directory:

    mkdir terraform

  2. Vai alla directory terraform:

    cd terraform

  3. Aggiungi un nuovo file, main.tf, alla directory:

    nano main.tf

  4. Aggiungi le seguenti risorse al file main.tf:

    1. Assegna l'ID del progetto:

      provider "google" {
project = "PROJECT_ID"
}

      Sostituisci PROJECT_ID con l'ID del tuo progetto.

    2. Abilita l'API Workflows: 

      # Enable Workflows API
resource "google_project_service" "default" {
  service            = "workflows.googleapis.com"
  disable_on_destroy = false
}

    3. Crea un account di servizio per il flusso di lavoro: 

      # Create a dedicated service account
resource "google_service_account" "default" {
  account_id   = "sample-workflows-sa"
  display_name = "Sample Workflows Service Account"
}

    4. Definisci il flusso di lavoro utilizzando la risorsa google_workflows_workflow:

      # Create a workflow
resource "google_workflows_workflow" "default" {
  name            = "sample-workflow"
  region          = "us-central1"
  description     = "A sample workflow"
  service_account = google_service_account.default.id
  labels = {
    env = "test"
  }
  user_env_vars = {
    url = "https://timeapi.io/api/Time/current/zone?timeZone=Europe/Amsterdam"
  }
  source_contents = <<-EOF
  # This is a sample workflow that you can replace with your source code
  #
  # The workflow does the following:
  # - Retrieves the current date from a public API and stores the
  #   response in `currentDate`
  # - Retrieves a list of Wikipedia articles from a public API related
  #   to the day of the week stored in `currentDate`
  # - Returns the list of articles in the workflow output
  #
  # Note that when you define workflows in Terraform, variables must be
  # escaped with two dollar signs ($$) and not a single sign ($)

  - getCurrentDate:
      call: http.get
      args:
          url: $${sys.get_env("url")}
      result: currentDate
  - readWikipedia:
      call: http.get
      args:
          url: https://en.wikipedia.org/w/api.php
          query:
              action: opensearch
              search: $${currentDate.body.dayOfWeek}
      result: wikiResult
  - returnOutput:
      return: $${wikiResult.body[1]}
EOF

  depends_on = [google_project_service.default]
}

Nel flusso di lavoro di esempio vengono utilizzati i seguenti argomenti:

  • name: il nome del tuo workflow.
  • region: la posizione del flusso di lavoro.
  • description: una descrizione del tuo flusso di lavoro.
  • service_account: l'indirizzo email o l'ID univoco dell'account di servizio associato alla versione più recente del flusso di lavoro. Questo account di servizio rappresenta l'identità del flusso di lavoro e determina le autorizzazioni di cui dispone. Se non specifichi un account di servizio durante la creazione del flusso di lavoro, il flusso di lavoro utilizza l'account di servizio Compute Engine predefinito per la sua identità. Per saperne di più, consulta Concedere un'autorizzazione dei flussi di lavoro per l'accesso alle risorse Google Cloud.
  • labels: un elenco di coppie di etichette chiave/valore da assegnare a questo flusso di lavoro per aiutarti a organizzare le istanze Google Cloud. Per maggiori informazioni, vedi Che cosa sono le etichette?
  • user_env_vars: variabili di ambiente definite dall'utente associate a questa revisione del flusso di lavoro. Per ulteriori informazioni, consulta Utilizzare le variabili di ambiente.
  • source_contents: il codice di Workflows da eseguire. Per il limite di dimensioni dei file, consulta Limiti delle risorse.

Altri argomenti facoltativi sono:

  • crypto_key_name: l'ID risorsa per una chiave Cloud Key Management Service nel seguente formato:

    projects/PROJECT_NAME/locations/LOCATION/keyRings/KEY_RING/cryptoKeys/KEY_NAME

    Per saperne di più, consulta Utilizzare le chiavi di crittografia gestite dal cliente.

  • call_log_level: il livello di registrazione da applicare alle chiamate e alle risposte alle chiamate durante le esecuzioni di questo flusso di lavoro. I valori possibili sono:

    • CALL_LOG_LEVEL_UNSPECIFIED
    • LOG_ALL_CALLS
    • LOG_ERRORS_ONLY
    • LOG_NONE

    Per ulteriori informazioni, consulta Registrazione delle chiamate.

  • project: l'ID del progetto a cui appartiene la risorsa. Se non viene fornito, viene utilizzato il progetto del fornitore.

  • name_prefix: crea un nome univoco che inizia con il prefisso specificato. Se questo e name non sono specificati, viene scelto un valore casuale per il nome.

Crea ed esegui il flusso di lavoro

Esegui il deployment delle risorse Terraform per creare il flusso di lavoro, quindi eseguilo.

  1. Inizializza Terraform nella directory:

    terraform init

  2. Verifica che le modifiche proposte con Terraform corrispondano al piano previsto:

    terraform plan

    Puoi ignorare la nota relativa all'utilizzo dell'opzione -out.

  3. Crea il flusso di lavoro:

    terraform apply

  4. Al prompt Inserisci un valore, digita yes per procedere con la creazione delle risorse.

  5. Verifica che sia stato creato un flusso di lavoro:

    gcloud workflows list --location us-central1

    L'output dovrebbe essere simile al seguente:

    NAME                                                                    STATE   REVISION_ID  UPDATE_TIME
projects/project-name/locations/us-central1/workflows/sample-workflow   ACTIVE  000001-f9a   2024-02-24T13:38:58.353765906Z

  6. Facoltativamente, puoi eseguire il flusso di lavoro:

    gcloud workflows execute sample-workflow

Esegui la pulizia

Per evitare che al tuo account Google Cloud vengano addebitati costi relativi alle risorse utilizzate su questa pagina, elimina il progetto Google Cloud con le risorse.

  1. Elimina tutte le risorse che hai creato con Terraform: 
    terraform destroy
  2. Elimina il flusso di lavoro creato: 
    gcloud workflows delete sample-workflow
     Quando ti viene chiesto se vuoi continuare, inserisci y.
  3. In alternativa, puoi eliminare il progetto Google Cloud per evitare addebiti. L'eliminazione del progetto Google Cloud interrompe la fatturazione per tutte le risorse utilizzate al suo interno.

      Delete a Google Cloud project:

      gcloud projects delete PROJECT_ID

Passaggi successivi