Tutorial do Terraform

Como configurar o ambiente

Neste tutorial, você executa comandos no Cloud Shell. O Cloud Shell é um ambiente com a Google Cloud CLI pré-instalada, incluindo a Google Cloud CLI e os valores já definidos para o projeto atual. O Cloud Shell pode demorar vários minutos para ser inicializado.

Abra o Cloud Shell

Como preparar o aplicativo

No Cloud Shell, execute as seguintes etapas:

1. Clone o repositório de aplicativos de amostra para sua instância do Cloud Shell:

   git clone https://github.com/GoogleCloudPlatform/nodejs-docs-samples.git

2. Mude para o diretório que contém os exemplos de código de exemplo das funções do Cloud Run:

   cd nodejs-docs-samples/functions

   A amostra Node.js usada neste tutorial é uma função HTTP básica "Hello World".

Crie seu arquivo main.tf.

1. No diretório nodejs-docs-samples/functions/, crie um arquivo main.tf para a configuração do Terraform:

   touch main.tf
   

2. Copie esta configuração do Terraform para seu arquivo main.tf:

   terraform {
     required_providers {
       google = {
         source  = "hashicorp/google"
         version = ">= 4.34.0"
       }
     }
   }
   
   resource "random_id" "default" {
     byte_length = 8
   }
   
   resource "google_storage_bucket" "default" {
     name                        = "${random_id.default.hex}-gcf-source" # Every bucket name must be globally unique
     location                    = "US"
     uniform_bucket_level_access = true
   }
   
   data "archive_file" "default" {
     type        = "zip"
     output_path = "/tmp/function-source.zip"
     source_dir  = "functions/hello-world/"
   }
   resource "google_storage_bucket_object" "object" {
     name   = "function-source.zip"
     bucket = google_storage_bucket.default.name
     source = data.archive_file.default.output_path # Add path to the zipped function source code
   }
   
   resource "google_cloudfunctions2_function" "default" {
     name        = "function-v2"
     location    = "us-central1"
     description = "a new function"
   
     build_config {
       runtime     = "nodejs16"
       entry_point = "helloHttp" # Set the entry point
       source {
         storage_source {
           bucket = google_storage_bucket.default.name
           object = google_storage_bucket_object.object.name
         }
       }
     }
   
     service_config {
       max_instance_count = 1
       available_memory   = "256M"
       timeout_seconds    = 60
     }
   }
   
   resource "google_cloud_run_service_iam_member" "member" {
     location = google_cloudfunctions2_function.default.location
     service  = google_cloudfunctions2_function.default.name
     role     = "roles/run.invoker"
     member   = "allUsers"
   }
   
   output "function_uri" {
     value = google_cloudfunctions2_function.default.service_config[0].uri
   }

3. Edite o arquivo main.tf para garantir que ele tenha os valores corretos dos itens a seguir. Você precisa editar esse arquivo sempre que a configuração mudar (por exemplo, para usar um ambiente de execução diferente ou implantar uma função diferente):

   • Ambiente de execução: neste exemplo, substitua nodejs16 pelo ambiente de execução mais recente do Node.js nodejs20.
   • Ponto de entrada da função: neste exemplo, o ponto de entrada da função é helloHttp.
   • Caminho para o diretório de origem: neste exemplo, mude source_dir para helloworld/helloworldHttp .
   • A configuração member="allUsers" do IAM não vai funcionar se o projeto estiver sujeito a uma política da organização de restrição de domínio que restrinja a concessão de papéis do IAM ao principal allUsers. Use com cuidado na produção e considere uma lista de membros mais restrita, se possível.

Inicialize o Terraform

No diretório nodejs-docs-samples/functions/ que contém o arquivo main.tf, execute este comando para adicionar os plug-ins necessários e criar o diretório .terraform:

terraform init

Aplique a configuração do Terraform:

No diretório nodejs-docs-samples/functions/ que contém o arquivo main.tf, implante a função aplicando a configuração. Quando solicitado, digite yes.

terraform apply

Testar a função

1. Quando a implantação da função estiver concluída, anote a propriedade ou encontre-a usando o seguinte comando:

   gcloud functions describe function-v2 --gen2 --region=us-central1 --format="value(serviceConfig.uri)"
   

2. Faça uma solicitação a este URL para ver a mensagem "Hello World" da sua função. Observe que a função é implantada exigindo autenticação. Portanto, é necessário fornecer as credenciais na sua solicitação:

   curl -H "Authorization: Bearer $(gcloud auth print-identity-token)" YOUR_FUNCTION_URL

Limpar

Depois de concluir o tutorial, exclua tudo o que foi criado para que você não tenha custos adicionais.

O Terraform permite remover todos os recursos definidos no arquivo de configuração executando o comando terraform destroy no diretório nodejs-docs-samples/functions/ que contém o arquivo main.tf:

terraform destroy

Digite yes para permitir que o Terraform exclua seus recursos.